tools/pkgs/fawltydeps/default.nix

{ lib
, poetry2nix
, fetchFromGitHub
, python310
}:

let
  poetryOverrides = poetry2nix.defaultPoetryOverrides.extend (full: prev: {
    colorama = prev.colorama.overridePythonAttrs (old: {
      buildInputs = old.buildInputs ++ [ prev.hatchling ];
    });
    iniconfig = prev.iniconfig.overridePythonAttrs (old: {
      buildInputs = old.buildInputs ++ [ prev.hatchling prev.hatch-vcs ];
    });
    filelock = prev.filelock.overridePythonAttrs (old: {
      buildInputs = old.buildInputs ++ [ prev.hatchling prev.hatch-vcs ];
    });
    packaging = prev.packaging.overridePythonAttrs (old: {
      buildInputs = old.buildInputs ++ [ prev.flit-core ];
    });
    pathspec = prev.pathspec.overridePythonAttrs (old: {
      buildInputs = old.buildInputs ++ [ prev.flit-core ];
    });
    nox = prev.nox.overridePythonAttrs (old: {
      buildInputs = old.buildInputs ++ [ prev.setuptools ];
    });
    exceptiongroup = prev.exceptiongroup.overridePythonAttrs (old: {
      buildInputs = old.buildInputs ++ [ prev.flit-scm ];
    });
    pip-requirements-parser = prev.pip-requirements-parser.overridePythonAttrs (old: {
      dontConfigure = true;
    });
  });

  src = fetchFromGitHub {
    owner = "tweag";
    repo = "FawltyDeps";
    rev = "2f9338d3ceb0c1954500f2cbede16ce223bfb160";
    sha256 = "sha256-h5jWeJ5ZfrTuGZr14nUFaNFMCRlpBzDxfFKRYTqxFDI=";
  };
in
poetry2nix.mkPoetryApplication {
  version = "2023-03-16";
  python = python310;
  projectDir = "${src}";
  overrides = poetryOverrides;
}