neovim/default.nix

{ enableDevIcons ? false
, enableBarBar ? false
, enableTabby ? false
, enableOrgMode ? false
, viAlias ? false
, vimAlias ? false
, grammarFileTypes ? [ "nix" ]
, theme ? { }
, plugins ? { }
, wrapNeovim
, neovim-unwrapped
, tree-sitter
, neovimPlugins
, lib
, nix2lua
, substituteAll
, ...
}:

let
  inherit (builtins) catAttrs isFunction readFile;
  myLib = import ./lib.nix { inherit lib; } // {
    inherit substituteAll;
    inherit (nix2lua.lib) toLua;
  };

  pluginParams = neovimPlugins // {
    inherit plugins;
    inherit tree-sitter grammarFileTypes;
    inherit enableDevIcons enableTabby enableOrgMode;
    themeCfg = theme;
    lib = myLib;
  };

  callPlugin = op:
    if isFunction op then op pluginParams else import op pluginParams;
  callPlugins = list: map callPlugin list;

  pluginsSettings = callPlugins [
    ./plugins/config
    ./plugins/syntax
    ./plugins/git
    ./plugins/explorer
    ./plugins/theme
    ./plugins/lsp
    ./plugins/formatter
    ./plugins/ux
  ];

  basePlugins = [ neovimPlugins.plenary-nvim ];
  customPlugins = catAttrs "plugins" pluginsSettings;
  allPlugins = basePlugins ++ customPlugins;

  basicConfigs = map readFile [ ./config/basic.lua ];
  pluginConfigs = catAttrs "luaConfig" pluginsSettings;
  allConfigs = basicConfigs ++ pluginConfigs;
in
(wrapNeovim neovim-unwrapped {
  inherit viAlias;
  inherit vimAlias;

  withPython3 = false;
  withNodeJs = false;
  withRuby = false;

  configure = {
    customRC = myLib.mkLuaRc allConfigs;

    packages.myVimPackages = { start = allPlugins; };
  };
}).overrideAttrs (oldAttrs: {
  passthru = oldAttrs.passthru // {
    nix2lua = nix2lua.lib;
  };
})