nixeovim/modules/vim/keymap.nix

{ config, lib, ... }:

let cfg = config.vim.keymap; in
{
  options.vim.keymap = with lib; {
    _validate = mkOption {
      #                  buffer   mode     lhs      rhs
      type = with types; attrsOf (attrsOf (attrsOf (either str attrs)));
      visible = false;
      internal = true;
      readOnly = true;
    };
    set = mkOption {
      type = with types; listOf keymap;
      default = [ ];
    };
  };

  config = {
    vim.keymap._validate = lib.mkMerge
      (map
        ({ mode, lhs, rhs, buffer, ... }:
          let
            sourceModes = if builtins.isList mode then mode else [ mode ];
            unwrappedModes = lib.flatten (lib.flip map sourceModes (m:
              if m == "" then [ m "n" "x" "s" "o" ]
              else if m == "!" then [ m "i" "c" ]
              else if m == "v" then [ m "x" "s" ]
              else if m == "l" then [ m "i" "c" "l" ]
              else m
            ));

            buf = if buffer == null then "" else buffer;
          in
          lib.foldl lib.recursiveUpdate { }
            (lib.flip map unwrappedModes (m: {
              "${buf}"."${m}"."${lhs}" = rhs;
            }))
        )
        cfg.set);
  };
}