{ config, pkgs, lib, inputs, fontSize ? null, ... }:

let secrets = import ./secrets.nix; in
{
  nixpkgs.overlays = lib.mkAfter ((import ../../overlays) ++ [
    inputs.wired.overlays.default
    inputs.myneovim.overlays.default
    inputs.vnetod.overlay
    inputs.nil.overlays.default
  ]);

  users.users.jan = {
    isNormalUser = true;
    extraGroups = [
      "wheel" # Enable ‘sudo’ for the user.
      (lib.mkIf config.networking.networkmanager.enable "networkmanager")
      (lib.mkIf config.virtualisation.docker.enable "docker")
    ];
    shell = pkgs.zsh;
    inherit (secrets) initialHashedPassword;
  };

  home-manager = {
    useGlobalPkgs = true;
    useUserPackages = true;
    users.jan = { lib, ... }: {
      imports = [
        inputs.wired.homeManagerModules.default
        ./home.nix
      ];

      progs.alacritty.fontSize = lib.mkIf (fontSize != null) fontSize;

      home.stateVersion = config.system.stateVersion;
    };
  };

  nix.settings.trusted-users = lib.mkAfter [ "jan" ];
}