{ config, lib, pkgs, ... }:

let themeCfg = config.local.theme; in
{
  home.packages = with pkgs; [
    xclip # access x clipboard from a console
    dmenu # menu for x window system
    nitrogen # wallpaper manager
  ];

  xsession = {
    enable = true;

    windowManager.xmonad = {
      enable = true;
      enableContribAndExtras = true;

      haskellPackages = pkgs.unstable.haskellPackages;
      extraPackages = (hp: [
        hp.dbus
        hp.monad-logger
      ]);

      config = pkgs.substituteAll {
        src = ./xmonad_config.hs;
        inherit (themeCfg.bar) background mainText inactiveText;
        inherit (themeCfg.window) activeBorder inactiveBorder;
        inherit (themeCfg.highlights) critical warning success;
        inherit (themeCfg.syntax) mark1 mark2 mark3;
      };
    };

    initExtra = ''
      ${pkgs.nitrogen}/bin/nitrogen --restore &
    '';
  };

  services.flameshot = {
    enable = true;

    # See: https://github.com/flameshot-org/flameshot/blob/master/flameshot.example.ini
    settings = {
      General = {
        disabledTrayIcon = true;
        savePathFixed = true;
        showDesktopNotification = false;
        showSidePanelButton = true;
      };
    };
  };
}