system/users/jan/default.nix

{ config, pkgs, lib, inputs, extraHomeModule ? null, ... }:

let
  d2-vim-overlay = final: prev: {
    vimPlugins = prev.vimPlugins // {
      d2-vim = prev.vimUtils.buildVimPluginFrom2Nix {
        name = "vim-d2";
        src = inputs.d2-vim;
      };
    };
  };

in
{
  nixpkgs.overlays = lib.mkAfter [
    inputs.myneovim.overlays.default
    inputs.mytools.overlays.all
    inputs.nil.overlays.default
    inputs.vnetod.overlays.default
    inputs.wired.overlays.default
    d2-vim-overlay
  ];

  programs.zsh.enable = true;

  users.users.jan = {
    isNormalUser = true;
    extraGroups = [
      "wheel" # Enable ‘sudo’ for the user.
      (lib.mkIf config.networking.networkmanager.enable "networkmanager")
      (lib.mkIf config.virtualisation.docker.enable "docker")
    ];
    shell = pkgs.zsh;
    passwordFile = config.age.secrets.users-jan-passfile.path;
  };

  home-manager.users.jan = { lib, ... }: {
    imports = [
      inputs.wired.homeManagerModules.default
      ./home.nix
      extraHomeModule
    ];

    home.stateVersion = config.system.stateVersion;
  };

  nix.settings.trusted-users = lib.mkAfter [ "jan" ];

  age.secrets.users-jan-passfile.file = ../../secrets/users-jan-passfile.age;
}