system/nix/progs/himalaya.nix

{ lib, config, pkgs, ... }:

with lib;

let
  cfg = config.progs.himalaya;

  devHimalaya = pkgs.himalaya.overrideAttrs (oldAttrs: {
    src = builtins.fetchGit {
      url = "https://github.com/soywod/himalaya.git";
      ref = "development";
      rev = "ba8ef9adf6effc40674765f995d19e9cfd1a8636";
    };
  });

  bin = "${devHimalaya}/bin/himalaya";
in
{
  options.progs.himalaya = {
    enable = mkOption {
      type = types.bool;
      default = false;
      description = "Add himalaya with my personal configuration";
    };
  };
  
  config = mkIf cfg.enable {
    programs.himalaya = {
      enable = true;
      package = devHimalaya;
      settings = {
        default-page-size = 20;
        downloads-dir = "${config.home.homeDirectory}/downloads/email";
      };
    };

    programs.zsh.shellAliases = mkIf config.shell.zsh.enable {
      him = bin;
      himp = "${bin} -a personal";
      himf = "${bin} -a family";
      himw = "${bin} -a work";
    };
  };
}