--
-- xmonad example config file.
--
-- A template showing all available configuration hooks,
-- and how to override the defaults in your own xmonad.hs conf file.
--
-- Normally, you'd only override those defaults you care about.
--

import qualified Codec.Binary.UTF8.String as UTF8
import Control.Monad (replicateM_, sequence_)
import qualified DBus as D
import qualified DBus.Client as D
import Data.Map.Strict (Map)
import qualified Data.Map.Strict as Map
import Data.Monoid
import System.Exit
import XMonad
import XMonad.Actions.CycleSelectedLayouts (cycleThroughLayouts)
import XMonad.Actions.EasyMotion
  ( ChordKeys (..),
    EasyMotionConfig (..),
    selectWindow,
  )
import XMonad.Actions.Minimize (maximizeWindow, minimizeWindow, withLastMinimized)
import XMonad.Hooks.DynamicLog
import XMonad.Hooks.EwmhDesktops
import XMonad.Hooks.InsertPosition (Focus (Newer), Position (Below), insertPosition)
import XMonad.Hooks.ManageDocks
import XMonad.Hooks.ManageHelpers
  ( composeOne,
    doCenterFloat,
    isDialog,
    (-?>),
  )
import XMonad.Hooks.StatusBar
import XMonad.Hooks.StatusBar.PP
import XMonad.Layout.BoringWindows (boringWindows, focusDown, focusMaster, focusUp, swapDown, swapUp)
import XMonad.Layout.Gaps (gaps)
import XMonad.Layout.Grid
import XMonad.Layout.LimitWindows (limitWindows)
import XMonad.Layout.Minimize (minimize)
import XMonad.Layout.NoBorders (smartBorders)
import XMonad.Layout.Renamed (Rename (..), renamed)
import XMonad.Layout.Spacing (spacing)
import XMonad.Prompt (XPConfig (..), XPPosition (Top), XPType (..), XPrompt (..), mkComplFunFromList', mkXPromptWithModes)
import qualified XMonad.StackSet as W
import XMonad.Util.EZConfig
import qualified XMonad.Util.ExtensibleState as XS
import XMonad.Util.Run

-- The preferred terminal program, which is used in a binding below and by
-- certain contrib modules.
--
myTerminal = "wezterm start"

-- Whether focus follows the mouse pointer.
myFocusFollowsMouse = False

-- Whether clicking on a window to focus also passes the click to the window
myClickJustFocuses = False

-- Width of the window border in pixels.
--
myBorderWidth = 2

-- modMask lets you specify which modkey you want to use. The default
-- is mod1Mask ("left alt").  You may also consider using mod3Mask
-- ("right alt"), which does not conflict with emacs keybindings. The
-- "windows key" is usually mod4Mask.
--
myModMask = mod1Mask

-- Workspaces

webWs = "web"

finWs = "fin"

sysWs = "sys"

comWs = "com"

devWs = ["dev", "dev2", "dev3"]

myWorkspaces = [webWs] <> devWs <> [finWs, sysWs, comWs]

main :: IO ()
main = mkDbusClient >>= main'

main' :: D.Client -> IO ()
main' dbus =
  xmonad . docks . ewmhFullscreen . ewmh . dynProjects $
    def
      { -- simple stuff
        terminal = myTerminal,
        focusFollowsMouse = myFocusFollowsMouse,
        clickJustFocuses = myClickJustFocuses,
        borderWidth = myBorderWidth,
        modMask = myModMask,
        workspaces = myWorkspaces,
        normalBorderColor = "@inactiveBorder@",
        focusedBorderColor = "@activeBorder@",
        -- key bindings
        keys = myKeys,
        mouseBindings = myMouseBindings,
        -- hooks, layouts
        layoutHook = myLayoutHook,
        manageHook = myManageHook,
        handleEventHook = myEventHook,
        logHook = myPolybarLogHook dbus,
        startupHook = myStartupHook
      }
  where
    dynProjects = dynamicProjects myProjects

------------------------------------------------------------------------
-- Polybar settings (needs DBus client).
--
mkDbusClient :: IO D.Client
mkDbusClient = do
  dbus <- D.connectSession
  D.requestName dbus (D.busName_ "org.xmonad.log") opts
  return dbus
  where
    opts = [D.nameAllowReplacement, D.nameReplaceExisting, D.nameDoNotQueue]

-- Emit a DBus signal on log updates
dbusOutput :: D.Client -> String -> IO ()
dbusOutput dbus str =
  let opath = D.objectPath_ "/org/xmonad/Log"
      iname = D.interfaceName_ "org.xmonad.Log"
      mname = D.memberName_ "Update"
      signal = D.signal opath iname mname
      body = [D.toVariant $ UTF8.decodeString str]
   in D.emit dbus $ signal {D.signalBody = body}

polybarHook :: D.Client -> PP
polybarHook dbus =
  let wrapper c = wrap ("%{F" <> c <> "}") "%{F-}"
   in def
        { ppOutput = dbusOutput dbus,
          ppCurrent = wrapper "@success@",
          ppVisible = wrapper "@mark3@",
          ppUrgent = wrapper "@critical@",
          ppHidden = wrapper "@mark1@",
          ppHiddenNoWindows = wrapper "@inactiveText@",
          ppTitle = wrapper "@mark3@" . shorten 60
        }

myPolybarLogHook dbus = myLogHook <+> dynamicLogWithPP (polybarHook dbus)

------------------------------------------------------------------------
-- Layouts:

-- You can specify and transform your layouts by modifying these values.
-- If you change layout bindings be sure to use 'mod-shift-space' after
-- restarting (with 'mod-q') to reset your layout state to the new
-- defaults, as xmonad preserves your old layout settings by default.
--
-- The available layouts.  Note that each layout is separated by |||,
-- which denotes layout choice.
--
myLayoutHook = mirrorTiled ||| tiled ||| full
  where
    full = layout fullLayoutId Full
    tiled = layout tallLayoutId baseTiled
    mirrorTiled = layout mirrorTallLayoutId $ Mirror baseTiled

    layout n l = renamed [Replace n] $ avoidStruts . smartBorders . minimize . boringWindows $ l

    baseTiled = gapSpaced 5 $ Tall nmaster incRatio ratio
    nmaster = 1
    incRatio = (3 / 100)
    ratio = (1 / 2)

    gapSpaced g = spacing g . myGaps g
    myGaps gap = gaps [(U, gap), (D, gap), (L, gap), (R, gap)]

fullLayoutId = "Full"

tallLayoutId = "Tall"

mirrorTallLayoutId = "Mirror Tall"

------------------------------------------------------------------------
-- Startup hook

-- Perform an arbitrary action each time xmonad starts or is restarted
-- with mod-q.  Used by, e.g., XMonad.Layout.PerWorkspace to initialize
-- per-workspace layout choices.
--
-- By default, do nothing.
myStartupHook = return ()

------------------------------------------------------------------------
-- Status bars and logging

-- Perform an arbitrary action on each internal state change or X event.
-- See the 'XMonad.Hooks.DynamicLog' extension for examples.
--
myLogHook = return ()

------------------------------------------------------------------------
-- Event handling

-- * EwmhDesktops users should change this to ewmhDesktopsEventHook

--
-- Defines a custom handler function for X Events. The function should
-- return (All True) if the default handler is to be run afterwards. To
-- combine event hooks use mappend or mconcat from Data.Monoid.
--
myEventHook = mempty

------------------------------------------------------------------------
-- Window rules:

-- Execute arbitrary actions and WindowSet manipulations when managing
-- a new window. You can use this to, for example, always float a
-- particular program, or have a client always appear on a particular
-- workspace.
--
-- To find the property name associated with a program, use
-- > xprop | grep WM_CLASS
-- and click on the client you're interested in.
--
-- To match on the WM_NAME, you can use 'title' in the same way that
-- 'className' and 'resource' are used below.
--
myManageHook = manageApps
  where
    anyOf :: [Query Bool] -> Query Bool
    anyOf = foldl (<||>) (pure False)

    role = stringProperty "WM_WINDOW_ROLE"
    isPopup = role =? "pop-up"
    isPinentry = anyOf [className =? "Gcr-promter", className =? "Pinentry"]

    isWezterm = className =? "org.wezfurlong.wezterm"
    isAlacritty = className =? "Alacritty"
    isTerminal = anyOf [isWezterm, isAlacritty]

    tileBelow = insertPosition Below Newer
    manageApps =
      composeOne
        [ -- apps
          className =? "Gimp" -?> doFloat,
          -- general
          anyOf
            [ resource =? "desktop_window",
              resource =? "kdesktop"
            ]
            -?> doIgnore,
          anyOf
            [ isPopup,
              isDialog,
              isPinentry
            ]
            -?> doCenterFloat,
          isTerminal -?> tileBelow
        ]

------------------------------------------------------------------------
-- Key bindings. Add, modify or remove key bindings here.
--
myKeys conf =
  mkKeymap conf $
    apps_kb ++ workspaces_kb ++ windows_kb ++ layout_kb ++ system_kb ++ misc_kb
  where
    apps_kb =
      [ -- launch a terminal
        ("M-S-<Return>", spawn $ XMonad.terminal conf),
        -- launch a 'flameshot' to screenshot
        ("M-S-s", safeSpawn "flameshot" ["gui"]),
        -- launch 'librewolf' browser
        ("M-S-b", spawn "librewolf"),
        -- launch 'dmenu_run' to choose applications
        ("M-p", spawn "dmenu_run")
        -- Open calculator
        -- ("<XF86Calculator>", spawn "gnome-calculator"),
      ]

    workspaces_kb =
      --
      -- mod-[1..9], Switch to workspace N
      -- mod-shift-[1..9], Move client to workspace N
      --
      [ ("M-" ++ m ++ show k, windows $ f i)
        | (i, k) <- zip (XMonad.workspaces conf) [1 .. 9],
          (f, m) <- [(W.greedyView, ""), (W.shift, "S-")]
      ]

    windows_kb =
      [ -- close focused window
        ("M4-S-c", kill),
        -- Resize viewed windows to the correct size
        ("M-n", refresh),
        -- Easy moution to focus windows
        ("M-s", selectWindow easyMotionConfig >>= (`whenJust` windows . W.focusWindow)),
        -- Move focus to the next window
        ("M-j", focusDown),
        -- Move focus to the previous window
        ("M-k", focusUp),
        -- Move focus to the master window
        ("M-m", focusMaster),
        -- Swap the focused window and the master window
        ("M-<Return>", windows W.swapMaster),
        -- Swap the focused window with the next window
        ("M-S-j", swapDown),
        -- Swap the focused window with the previous window
        ("M-S-k", swapUp)
      ]
      where
        easyMotionConfig =
          def
            { sKeys = AnyKeys [xK_a, xK_o, xK_e, xK_u, xK_h, xK_t, xK_n, xK_s]
            }

    layout_kb =
      [ -- Rotate through the available layout algorithms
        -- ("M-<Space>", sendMessage NextLayout),
        ("M-<Space>", cycleThroughLayouts [fullLayoutId, mirrorTallLayoutId]),
        ("M-<Tab>", cycleThroughLayouts [tallLayoutId, mirrorTallLayoutId]),
        --  Reset the layouts on the current workspace to default
        ("M-S-<Space>", setLayout $ XMonad.layoutHook conf),
        -- Shrink the master area
        ("M-h", sendMessage Shrink),
        -- Expand the master area
        ("M-l", sendMessage Expand),
        -- Push window back into tiling
        ("M-t", withFocused $ windows . W.sink),
        -- Increment the number of windows in the master area
        ("M-,", sendMessage $ IncMasterN 1),
        -- Deincrement the number of windows in the master area
        ("M-.", sendMessage $ IncMasterN (-1)),
        -- Toggle the status bar gap
        -- Use this binding with avoidStruts from Hooks.ManageDocks.
        -- See also the statusBar function from Hooks.DynamicLog.
        ("M-b", toggleStruts),
        -- Minimize and maximize windows
        ("M4-m", withFocused minimizeWindow),
        ("M4-S-m", withLastMinimized maximizeWindow)
      ]
      where
        togglePolybar = spawn "polybar-msg cmd toggle &"
        toggleStruts = togglePolybar >> sendMessage ToggleStruts

    system_kb =
      [ -- Lock screen
        ("M4-l", spawn "betterlockscreen --lock --display 1 -- -e"),
        -- Quit xmonad
        ("M4-S-q", io exitSuccess)
      ]

    -- Use the following command `xev | sed -ne '/^KeyPress/,/^$/p'`
    -- to get key name
    misc_kb =
      [ ("M-o", projectPrompt myPromptConfig),
        -- Change volume
        ("<XF86AudioMute>", spawn "amixer -q sset Master toggle"),
        ("<XF86AudioRaiseVolume>", spawn "amixer -q sset Master 5%+"),
        ("<XF86AudioLowerVolume>", spawn "amixer -q sset Master 5%-"),
        -- Change keyboard brightness
        ("<XF86KbdBrightnessUp>", spawn (kdbBrightness "up")),
        ("<XF86KbdBrightnessDown>", spawn (kdbBrightness "down"))
      ]
      where kdbBrightness cmd = myTerminal ++ " -- @kdbBrightnessScriptPath@ " ++ cmd

------------------------------------------------------------------------
-- Mouse bindings: default actions bound to mouse events
--
myMouseBindings (XConfig {XMonad.modMask = modm}) =
  Map.fromList
    -- mod-button1, Set the window to floating mode and move by dragging
    [ ((modm, button1), \w -> focus w >> mouseMoveWindow w >> windows W.shiftMaster),
      -- mod-button2, Raise the window to the top of the stack
      ((modm, button2), \w -> focus w >> windows W.shiftMaster),
      -- mod-button3, Set the window to floating mode and resize by dragging
      ((modm, button3), \w -> focus w >> mouseResizeWindow w >> windows W.shiftMaster)
      -- you may also bind events to the mouse scroll wheel (button4 and button5)
    ]

myProjects :: [Project]
myProjects =
  [ -- my work
    Project
      { projectName = "bm-back",
        projectStartHook = do
          let workdir = "~/projects/binarymanagement/bm-back"
          spawn $ terminal' workdir $ Just "docker-compose -f docker-compose.dev.yml up -d"
          replicateM_ 3 $ spawn $ terminal workdir
      },
    Project
      { projectName = "bm-front",
        projectStartHook = do
          let workdir = "~/projects/binarymanagement/bm-front"
          replicateM_ 3 $ spawn $ terminal workdir
      },
    -- personal
    Project
      { projectName = "system",
        projectStartHook = replicateM_ 2 $ spawn $ terminal "~/repos/mynix/system"
      },
    Project
      { projectName = "neovim",
        projectStartHook = replicateM_ 2 $ spawn $ terminal "~/repos/mynix/neovim"
      }
  ]
  where
    terminal :: String -> String
    terminal wd = terminal' wd Nothing

    terminal' :: String -> Maybe String -> String
    terminal' wd' cmd' =
      myTerminal ++ workdir ++ command
      where
        workdir = " --cwd " ++ wd'
        command = case cmd' of
          Just c -> " -- " ++ c
          _ -> ""

myPromptConfig :: XPConfig
myPromptConfig =
  def
    { position = Top,
      font = "xft:Fira Code:size=12:antialias=true",
      borderColor = "@inactiveBorder@",
      bgColor = "@background@",
      fgColor = "@mainText@",
      bgHLight = "@background@",
      fgHLight = "@mark3@",
      height = 25
    }

------------------------------------------------------------------------
-- Project
type ProjectName = String

data Project = Project
  { projectName :: !ProjectName,
    projectStartHook :: !(X ())
  }

type ProjectTable = Map ProjectName Project

data ProjectState = ProjectState {projects :: !ProjectTable}

instance ExtensionClass ProjectState where
  initialValue = ProjectState Map.empty

data ProjectPrompt = ProjectPrompt XPConfig [ProjectName]

dynamicProjects :: [Project] -> XConfig a -> XConfig a
dynamicProjects ps c =
  c {startupHook = dynamicProjectsStartupHook ps <> startupHook c}

dynamicProjectsStartupHook :: [Project] -> X ()
dynamicProjectsStartupHook ps = XS.modify go
  where
    go :: ProjectState -> ProjectState
    go s = s {projects = update $ projects s}

    update :: ProjectTable -> ProjectTable
    update = Map.union (Map.fromList $ map entry ps)

    entry :: Project -> (ProjectName, Project)
    entry p = (projectName p, p)

instance XPrompt ProjectPrompt where
  showXPrompt (ProjectPrompt _ _) = "Choose Project: "

  completionFunction (ProjectPrompt c ns) = mkComplFunFromList' c ns

  modeAction (ProjectPrompt _ _) buf auto = do
    let name = if null auto then buf else auto
    ps <- XS.gets projects

    case Map.lookup name ps of
      Just p -> openProject p
      Nothing -> return ()

openProject :: Project -> X ()
openProject p = do
  -- kill all windows in the current workspace
  wins <- gets (W.integrate' . W.stack . W.workspace . W.current . windowset)
  sequence_ $ map killWindow wins

  projectStartHook p

projectPrompt :: XPConfig -> X ()
projectPrompt c = do
  ps <- XS.gets projects

  let names = Map.keys ps
      modes = [XPT $ ProjectPrompt c names]

  mkXPromptWithModes modes c
