nix2lua/lib.nix

/**
 * Copyright (C) 2022, Dmitriy Pleshevskiy <dmitriy@pleshevski.ru>
 *
 * nix2lua is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * nix2lua is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with nix2lua.  If not, see <https://www.gnu.org/licenses/>.
 */
let
  inherit (builtins) isString isFloat isInt isBool isList isAttrs isNull isPath;
  inherit (builtins) concatStringsSep filter mapAttrs attrValues;

  ################################################################################
  # Utils
  ################################################################################

  error = message: throw "[nix2lua] ${message}";
  warn = msg: builtins.trace "[nix2lua] warning: ${msg}";

  getType = expr: if isAttrs expr && expr ? _type then expr._type else null;

  validString = expr:
    if isString expr || isPath expr then toString expr
    else error "Value '${toString expr}' is not a valid string";

  ################################################################################
  # Low-Level
  ################################################################################

  isJoin = expr: getType expr == "_join";
  join = sep: expr:
    if isList expr then { _type = "_join"; sep = validString sep; parts = expr; }
    else error "Value '${toString expr}' is not supported for a join type";

  isLuaRaw = expr: getType expr == "raw";
  mkLuaRaw = expr:
    if isLuaRaw expr then
      { _type = "raw"; raw = expr.raw; }
    else if isString expr then
      { _type = "raw"; raw = expr; }
    else
      error "Value '${toString expr}' is not supported for a raw type";

  mkCall = fnName: args:
    let
      luaFn =
        if isString fnName && builtins.stringLength fnName > 0 then mkLuaRaw fnName
        else error "Value '${toString fnName}' is not a valid function name";
    in
    join "" (
      [ luaFn (mkLuaRaw "(") ]
      ++ [ (join ", " args) ]
      ++ [ (mkLuaRaw ")") ]
    );

  toLuaStr = expr: "\"${validString expr}\"";
  toLuaBool = expr: if expr then "true" else "false";

  isLuaNil = expr: getType expr == "nil";
  LuaNil = { _type = "nil"; };
  # DEPRECATED
  mkLuaNil = warn "`mkLuaNil` is deprecated. Use `LuaNil` instead" LuaNil;

  toLuaList = onValue: expr:
    let
      wrapObj = expr: "{ ${concatStringsSep ", " expr} }";
      excludeNull = expr: filter (v: !(isNull v)) expr;
    in
    wrapObj (excludeNull (map onValue expr));

  toLuaTable = onValue: expr: onValue (attrValues (mapAttrs mkNamedField expr));

  mkNamedField = name: expr: {
    _type = "table_field";
    name = validString name;
    value = toLua expr;
  };
  isNamedField = expr: getType expr == "table_field";
  toLuaNamedField = name: expr:
    if isNull expr then null
    else "[${toLuaStr name}] = ${expr}";

  toLuaInternal = depth: expr:
    let nextDepth = depth + 1; in
    if isJoin expr then concatStringsSep expr.sep (map (toLuaInternal depth) expr.parts)
    else if isLuaNil expr then "nil"
    else if isLuaRaw expr then expr.raw
    else if isNamedField expr then
      if depth > 0 then toLuaNamedField expr.name expr.value
      else error "You cannot render table field at the top level"
    else if isAttrs expr then toLuaTable (toLuaInternal nextDepth) expr
    else if isList expr then toLuaList (toLuaInternal nextDepth) expr
    else if isString expr || isPath expr then toLuaStr expr
    else if isFloat expr || isInt expr then toString expr
    else if isBool expr then toLuaBool expr
    else if isNull expr then null
    else error "Value '${toString expr}' is not supported yet";

  toLua = val: toLuaInternal 0 val;

in
{
  # low-level
  inherit join;

  inherit toLua;
  inherit LuaNil mkLuaRaw mkNamedField mkCall;
  # DEPRECATED
  inherit mkLuaNil;
}